Quantification of fluorescence spots intensity along the spot area

Hello all,
We would be happy for an advice.
We have a question concerning quantification of fluorescence spots in an image acquired with confocal microscope with an Airy scan detector (see image uploaded) .
The spots of the image represent protein clustering sites and we wish to evaluate the spots area along with integrating the fluorescence intensity throughout the spots area.
Currently, we use the ‘spot counter’ plug in Fiji to identify the spots and to evaluate the mean value of the spot intensity at the center of the spot using a square area with defined pixel length (e.g. 5x5 pixel square). What we wish to do is to get the mean fluorescence value of the entire spot with its unique shape. Our spots are of irregular shape and a square area tool to evaluate its intensity is not satisfying.
Can anybody help? any advice would be appreciated.
thanks a lot.

Good day!

Here is an ImageJ-macro that does what you want:

// imagej-macro "spotMeasures" (Herbie G., 12. Dec. 2018)
requires( "1.52i" );
setOption("BlackBackground", true);
run("Set Measurements...", "area mean standard median redirect=None decimal=2");
run("Clear Results");
setBatchMode(true);
run("Duplicate...", "title=temp");
setAutoThreshold("Default dark");
run("Convert to Mask");
run("Analyze Particles...", "add");
close("temp");
roiManager("Show All");
roiManager("multi-measure measure_all append");
run("Summarize");
run("From ROI Manager");
run("Labels...", "color=white font=12 draw");
setBatchMode(false);
exit();
// imagej-macro "spotMeasures" (Herbie G., 12. Dec. 2018)

Paste the above macro code to an empty macro window (Plugins >> New >> Macro) and run it with an image open in ImageJ.

Please note that if you are not happy with the spot segmentation, you could try another automatic threshold scheme. Presently the “Default”-scheme is used.

If you like other measurements you need to adapt the “Set Measurements…” code line accordingly.

Finally, if you don’t like to see the spot contours, you can either hide or delete them from the ImageJ-menu item “Image >> Overlay”.

Please study the ImageJ UserGuide thoroughly to become more familiar with its functionality.

Regards

Herbie

1 Like

thank you very much :slightly_smiling_face:

Dear Herbie,
First, again, thanks a lot for your help.

We have implemented the code you sent, and indeed it does the job. its exactly what we needed. Thanks. we can add to this code a function for integrating all the fluorescence signal within the defined cluster area, rather than just working with the mean values. this would serve us better.

We have another question- the the speckled membranous clustering sites we see on the image is a result of interaction with another cytoplasmic partner protein. we usually acquire images of the same cell from two channels, one marked red (the ion channel protein) and the other one marked green (GFP fusion of the partner scaffold protein). The interaction between the two proteins is manifested by their co-localization pattern within the clustering sites . Our question is whether we can perform the same analysis (areas+ integrated intensity) on the merged yellow co-localization image? we upload here an example of the same cell recorded by the two green and red channels.
we would be happy for any advice.
Thanks a lot,
Limor and Ofer

Good day!

integrating all the fluorescence signal within the defined cluster area

You mean the integral values instead of the mean values? Use the following code line

run("Set Measurements...", "area mean standard integrated median redirect=None decimal=2");

and please become more familiar with ImageJ.

Our question is whether we can perform the same analysis (areas+ integrated intensity) on the merged yellow co-localization image?

Of course you can, but I highly recommend asking someone who is experienced with co-localization analysis because it appears to be a much more complicated subject and there exist ImageJ-plugins that are specialized for this task. I never used them and I have no experience at all in this field.

There are however many post concerning co-localization analysis in this Forum and you really should search the threads and follow the suggestions that are given by those who are in the know.

Regards

Herbie

1 Like

thank you again :slightly_smiling_face: